Delphi shellexecute коды ошибок

WinApi Функция ShellExecute

писание:
function ShellExecute(hWnd: HWND; Operation, FileName, Parameters,
Directory: PChar; ShowCmd: Integer): HINST;

Функция может открыть или напечатать определенный файл. Исполняет как Windows-приложения так и открывает файлы-документы.
Например с файлами типа «.txt» связан Блокнот «Notepad.exe» и запуск файла «my.txt» приведет к тому, что будет запущен Блокнот и в него будет передан параметр с именем файла.

Также с помощью этой функци можно в проводнике открыть папку.

Параметры:
hWnd: Хендл родителя запускаемого приложения.

Operation: Строка определяющая команду для исполнения. Может содержать:
«open» — открыть файл определенный параметром FileName.
«print» — напечатать файл определенный параметром FileName.
«explore» — открыть папку определенную параметром FileName.
Если параметр Operation равен nil, то по умолчанию выполняется операция «open».

FileName: Определяет имя файла или папки для открытия или печати. Функция может запускать файл на исполнение или документ на печать.

Parameters: определяет параметры передаваемые при запуске исполняемого приложения. Бессмысленно его использовать при запуске документа. Параметр можеть быть равен Nil.

Directory: опеределяет каталог по умолчанию(рабочий каталог). Получитьустановить можно с помощью функций GetCurrentDirectory, SetCurrentDirectory.

ShowCmd: определяет режим открытия файла. См. константы открытияпоказа SW_.

Возвращаемые значения
Функция возвращает Хендл открытого приложения или сервера DDE. Возвращаемое значение должно быть больше 32. В противном случае это ошибка:

0 — Системе не хватает памяти, выполняемый файл испорчен или нехватает ресурсов.
ERROR_FILE_NOT_FOUND — файл не найден.
ERROR_PATH_NOT_FOUND — путь не найден.
ERROR_BAD_FORMAT — .EXE-Файл неверен (не-Win32.EXE или ошибка в .EXE).
SE_ERR_ACCESSDENIED — Операционная Система отвергла доступ к файлу.
SE_ERR_ASSOCINCOMPLETE — неправильная или неполная ассоциация с файлом.
SE_ERR_DDEBUSY — транзакция DDE не может завершаться поскольку были запущены другие транзакции.

SE_ERR_DDEFAIL — транзакция DDE потерпела неудачу.
SE_ERR_DDETIMEOUT — транзакция DDE не могла завершаться поскольку запрос несинхронизированный.
SE_ERR_DLLNOTFOUND — динамическая библиотека(.DLL) не обнаружена.
SE_ERR_FNF — файл не найден.
SE_ERR_NOASSOC — нет приложения ассоцированного с данным типом файла.
SE_ERR_OOM — недостаточно памяти для завершения операции.
SE_ERR_PNF — путь не найден.
SE_ERR_SHARE — разделение(shared) файла неверно.

Материал взят из:
Русская спpавка по Windows API

Последние из рубрики

• SetWindowText
• SetWindowWord winapi
• SHBrowseForFolder winapi

You have to use full path to the application you are trying to start.

ExtractFilePath(Application.ExeName) will give you full path to your launcher exe.

Solution 1: using ShellExecute

procedure TFMain.ImgBtn1Click(Sender: TObject);
var 
  ExecuteResult: integer;
  Path: string;
begin
  Path := IncludeTrailingPathDelimiter(ExtractFilePath(Application.ExeName));
  ExecuteResult := ShellExecute(0, nil, PChar(Path + 'binstarter.exe'), '-lang rus', nil, SW_SHOWNORMAL);
  if ExecuteResult <= 32 then ShowMessage('Error: ' + IntToStr(ExecuteResult));
end;

You can find list of error codes at: ShellExecute function documentation

Most common error codes:

• ERROR_FILE_NOT_FOUND 0x2
• ERROR_PATH_NOT_FOUND 0x3

Solution 2: using ShellExecuteEx

var
  FileName, Parameters, Folder: string;
  sei: TShellExecuteInfo;
  Error: DWORD;
  OK: boolean;
begin
  Folder := IncludeTrailingPathDelimiter(ExtractFilePath(Application.ExeName)) + 'bin';
  FileName := Folder + 'starter.exe';
  Parameters := '-lang rus';
  ZeroMemory(@sei, SizeOf(sei));
  sei.cbSize := SizeOf(sei);
  sei.lpFile := PChar(FileName);
  sei.lpParameters := PChar(Parameters);
  sei.lpDirectory := PChar(Folder);
  sei.nShow := SW_SHOWNORMAL;
  OK := ShellExecuteEx(@sei);
  if not OK then
    begin
      Error := GetLastError;
      ShowMessage('Error: ' + IntToStr(Error));
    end;
end;

ShellExecuteEx documentation

Solution 3: using CreateProcess

function ExecuteProcess(const FileName, Params: string; Folder: string; WaitUntilTerminated, WaitUntilIdle, RunMinimized: boolean;
  var ErrorCode: integer): boolean;
var
  CmdLine: string;
  WorkingDirP: pchar;
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
begin
  Result := true;
  CmdLine := '"' + FileName + '" ' + Params;
  if Folder = '' then Folder := ExcludeTrailingPathDelimiter(ExtractFilePath(FileName));
  ZeroMemory(@StartupInfo, SizeOf(StartupInfo));
  StartupInfo.cb := SizeOf(StartupInfo);
  if RunMinimized then
    begin
      StartupInfo.dwFlags := STARTF_USESHOWWINDOW;
      StartupInfo.wShowWindow := SW_SHOWMINIMIZED;
    end;
  if Folder <> '' then WorkingDirP := pchar(Folder)
  else WorkingDirP := nil;
  if not CreateProcess(nil, pchar(CmdLine), nil, nil, false, 0, nil, WorkingDirP, StartupInfo, ProcessInfo) then
    begin
      Result := false;
      ErrorCode := GetLastError;
      exit;
    end;
  with ProcessInfo do
    begin
      CloseHandle(hThread);
      if WaitUntilIdle then WaitForInputIdle(hProcess, INFINITE);
      if WaitUntilTerminated then
        repeat
          Application.ProcessMessages;
        until MsgWaitForMultipleObjects(1, hProcess, false, INFINITE, QS_ALLINPUT) <> WAIT_OBJECT_0 + 1;
      CloseHandle(hProcess);
    end;
end;

procedure TForm1.Button4Click(Sender: TObject);
var
  FileName, Parameters, Folder: string;
  Error: integer;
  OK: boolean;
begin
  Folder := IncludeTrailingPathDelimiter(ExtractFilePath(Application.ExeName)) + 'bin';
  FileName := Folder + 'starter.exe';
  Parameters := '-lang rus';
  OK := ExecuteProcess(FileName, Parameters, Folder, false, false, false, Error);
  if not OK then
    begin
      Error := GetLastError;
      ShowMessage('Error: ' + IntToStr(Error));
    end;
end;

CreateProcess documentation